استورد أساسي::رايليب.

دالة ابدأ_الرئيسية() -> ص64 {
    دع مفتوح = رايليب::هيئ_نافذة(480, 300, "PNG sprites / صور متحركة").
    إذا لا مفتوح::نجاح { اطبع(مفتوح::الخطأ::الرسالة). أرجع 1. }
    دع محمل = رايليب::حمل_نسيجا("docs/examples/assets/raylib-sprites.png").
    إذا لا محمل::نجاح { اطبع(محمل::الخطأ::الرسالة). أرجع 2. }
    دع نسيج = محمل::قيمة.
    دع مرادف = نسيج.
    إذا رايليب::عرض_النسيج(نسيج)::قيمة لا يطابق 32 أو رايليب::ارتفاع_النسيج(نسيج)::قيمة لا يطابق 16 { أرجع 3. }
    دع مرشح = رايليب::اضبط_مرشح_النسيج(نسيج, رايليب::مرشح_نسيج_نقطي).
    دع التفاف = رايليب::اضبط_التفاف_النسيج(نسيج, رايليب::التفاف_نسيج_تثبيت).
    دع معدل_الإطارات = رايليب::اضبط_معدل_الإطارات(60).
    إذا لا مرشح::نجاح أو لا التفاف::نجاح أو لا معدل_الإطارات::نجاح { أرجع 4. }
    دع كاميرا = رايليب::كاميرا2 {
        إزاحة: رايليب::متجه2 { س: 15.0, ص: 10.0 }, هدف: رايليب::متجه2 { س: 0.0, ص: 0.0 },
        دوران: 0.0, تكبير: 1.0
    }.
    دع أول = رايليب::مستطيل { س: 24.0, ص: 24.0, عرض: 32.0, ارتفاع: 16.0 }.
    دع ثان = رايليب::مستطيل { س: 30.0, ص: 28.0, عرض: 32.0, ارتفاع: 16.0 }.
    دع تصادم = رايليب::هل_يتداخل_مستطيلان(أول, ثان).
    دع تداخل = رايليب::مستطيل_التداخل(أول, ثان).
    إذا لا تصادم::نجاح أو لا تداخل::نجاح { أرجع 16. }
    إذا لا تصادم::قيمة { أرجع 17. }
    متغير إطار: ص32 = 0.
    طالما إطار < 20 {
        إذا لا رايليب::ابدأ_الرسم()::نجاح أو لا رايليب::امسح_الخلفية(رايليب::أبيض_رايليب)::نجاح { أرجع 5. }
        إذا لا رايليب::ابدأ_وضع_ثنائي_الأبعاد(كاميرا)::نجاح { أرجع 6. }
        إذا لا رايليب::ارسم_نسيجا(نسيج, 24, 24, رايليب::أبيض)::نجاح { أرجع 7. }
        إذا لا رايليب::ارسم_نسيجا_بمتجه(نسيج, رايليب::متجه2 { س: 100.0, ص: 24.0 }, رايليب::أزرق_سماوي)::نجاح { أرجع 8. }
        إذا لا رايليب::ارسم_نسيجا_موسعا(نسيج, رايليب::متجه2 { س: 40.0, ص: 110.0 }, -10.0, 4.0, رايليب::أبيض)::نجاح { أرجع 9. }
        إذا لا رايليب::ارسم_جزء_نسيج(نسيج, رايليب::مستطيل { س: 16.0, ص: 0.0, عرض: -16.0, ارتفاع: 16.0 },
            رايليب::متجه2 { س: 250.0, ص: 24.0 }, رايليب::أبيض)::نجاح { أرجع 10. }
        إذا لا رايليب::ارسم_نسيجا_متقدما(نسيج, رايليب::مستطيل { س: 16.0, ص: 0.0, عرض: 16.0, ارتفاع: -16.0 },
            رايليب::مستطيل { س: 330.0, ص: 160.0, عرض: -96.0, ارتفاع: 96.0 },
            رايليب::متجه2 { س: 48.0, ص: 48.0 }, 25.0, رايليب::لون { أحمر: 255, أخضر: 255, أزرق: 255, ألفا: 210 })::نجاح { أرجع 11. }
        إذا لا رايليب::ارسم_محيط_مستطيل_موسعا(تداخل::قيمة, 1.0, رايليب::أحمر)::نجاح { أرجع 18. }
        إذا لا رايليب::أنه_وضع_ثنائي_الأبعاد()::نجاح { أرجع 12. }
        إذا إطار يطابق 19 {
            إذا لا رايليب::حرر_النسيج(مرادف)::نجاح أو رايليب::هل_النسيج_صالح(نسيج) { أرجع 13. }
        }
        إذا لا رايليب::أنه_الرسم()::نجاح { أرجع 14. }
        إطار = إطار + 1.
    }
    إذا لا رايليب::حرر_النسيج(نسيج)::نجاح أو لا رايليب::أغلق_النافذة()::نجاح { أرجع 15. }
    اطبع("texture sprites complete").
    أرجع 0.
}